-- Módulo de implementación del tipo genérico "monticulo".
-- Véase la documentación del módulo de definición.
--
-- Versión: 2.0
-- Fecha: 19-XI-99
-- Autor: Javier Campos Laclaustra (jcampos@posta.unizar.es)
--
package body monticulos is
  procedure creaVacio(c:out monticulo) is
  begin
    c.num:=0;
  end creaVacio;
	
  procedure encola(c:in out monticulo; e:in elemento) is
    i:integer range 0..maxNum; debeSubir:boolean; aux:elemento;
  begin
    c.num:=c.num+1;
    c.dato(c.num):=e;
    i:=c.num;
    if i>1 then
      debeSubir:=c.dato(i)<c.dato(i/2);
    else
      debeSubir:=false;
    end if;
    while i>1 and debeSubir loop
      aux:=c.dato(i);
      c.dato(i):=c.dato(i/2);
      c.dato(i/2):=aux;
      i:=i/2;
      if i>1 then
        debeSubir:=c.dato(i)<c.dato(i/2);
      else
        debeSubir:=false;
      end if;
    end loop;
  end encola;
	
  function menor(c:monticulo) return elemento is
  begin
    return c.dato(1);
  end menor;
	
  procedure decola(c:in out monticulo) is
    i,j:integer range 1..maxNum; aux:elemento;
  begin
    c.dato(1):=c.dato(c.num);
    c.num:=c.num-1;
    i:=1;
    while i<=c.num/2 loop
      if c.dato(2*i)<c.dato(2*i+1) or 2*i=c.num then 
        j:=2*i;
      else 
        j:=2*i+1;
      end if;
      if c.dato(j)<c.dato(i) then
        aux:=c.dato(i);
        c.dato(i):=c.dato(j);
        c.dato(j):=aux;
        i:=j;
      else
        i:=c.num;
      end if;
    end loop;
  end decola;
	
  function esVacio(c:monticulo) return boolean is
  begin
    return c.num=0;
  end esVacio;

  function longitud(c:monticulo) return natural is
  begin
    return c.num;
  end longitud;

end monticulos;